blob: 502083619611dfc7f646bebaa772a6645343b671 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit desktop virtualx xdg cmake
DESCRIPTION="Share a mouse and keyboard between computers (fork of Synergy)"
HOMEPAGE="https://github.com/debauchee/barrier"
SRC_URI="https://github.com/debauchee/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="gui libressl test"
RESTRICT="!test? ( test )"
RDEPEND="
net-misc/curl
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXext
x11-libs/libXi
x11-libs/libXinerama
x11-libs/libXrandr
x11-libs/libXtst
gui? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
net-dns/avahi[mdnsresponder-compat]
)
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
"
DEPEND="
${RDEPEND}
dev-cpp/gtest
x11-base/xorg-proto
"
PATCHES=(
"${FILESDIR}"/${P}-tests.patch
"${FILESDIR}"/${P}-gtest.patch
)
DOCS=(
ChangeLog
README.md
doc/${PN}.conf.example{,-advanced,-basic}
)
src_configure() {
local mycmakeargs=(
-DBARRIER_BUILD_GUI=$(usex gui)
-DBARRIER_BUILD_INSTALLER=OFF
-DBARRIER_BUILD_TESTS=$(usex test)
-DBARRIER_REVISION=00000000
-DBARRIER_USE_EXTERNAL_GTEST=ON
-DBARRIER_VERSION_STAGE=gentoo
)
cmake_src_configure
}
src_test() {
"${BUILD_DIR}"/bin/unittests || die
virtx "${BUILD_DIR}"/bin/integtests || die
}
src_install() {
cmake_src_install
einstalldocs
doman doc/${PN}{c,s}.1
if use gui; then
doicon -s scalable res/${PN}.svg
doicon -s 256 res/${PN}.png
make_desktop_entry ${PN} Barrier ${PN} Utility
fi
}
|
GitWeb