dev-python/celery: add 5.1.1

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

2 files changed, 103 insertions, 0 deletions

diff --git a/dev-python/celery/Manifest b/dev-python/celery/Manifest
index 601e883ba..22d075e14 100644
--- a/dev-python/celery/Manifest
+++ b/dev-python/celery/Manifest
@@ -1 +1,2 @@
 DIST celery-5.1.0.tar.gz 1468143 BLAKE2B e066941c6d214bb6bb9afec8100a2fa5e5c96da0f46cb0821d0cbf8aa6607e22320a1f46d48b7aae0f91f4d6c1d9d2143f50b0927a186f8aebc13d3fcc48b6af SHA512 78368767d1acb799d96036a4f0dab03b085c9a393f52f184080be1100a3c55c97b492d37be0944eca2cd55cfa21128c80e19537233702b1ee136027e47f889f8
+DIST celery-5.1.1.tar.gz 1471516 BLAKE2B bfdabf255cffa19deb80607c3a2063b6dd8c56a803a991453b8b07914e75630fee9d189ccb8e6be1f7e88e43fb22d31353968ffea222d75a7b7765ec3a5148b5 SHA512 b50fe494ec8346b5a90236536dbc809341b4b2328c1a2b7485210fb88cd5d8142f3e53b40c6b49e9e495eecaca1abcec2000f2af6d2f2bd719265410802eb572
diff --git a/dev-python/celery/celery-5.1.1.ebuild b/dev-python/celery/celery-5.1.1.ebuild
new file mode 100644
index 000000000..c200bfdd9
--- /dev/null
+++ b/dev-python/celery/celery-5.1.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+MYPV="${PV/_beta/b}"
+PYTHON_COMPAT=( python3_8 )
+
+inherit bash-completion-r1 distutils-r1 eutils optfeature
+
+DESCRIPTION="Asynchronous task queue/job queue based on distributed message passing"
+HOMEPAGE="
+	http://celeryproject.org
+	https://pypi.org/project/celery
+	https://github.com/celery/celery
+"
+SRC_URI="https://github.com/celery/celery/archive/v${MYPV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MYPV}"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+# There are a number of other optional 'extras'
+IUSE="examples"
+#RESTRICT="!test? ( test )"
+RESTRICT="test" # 'celery' not found in `markers` configuration option
+
+RDEPEND="
+	>=dev-python/billiard-3.6.4.0[${PYTHON_USEDEP}]
+	<dev-python/billiard-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/click-7[${PYTHON_USEDEP}]
+	<dev-python/click-8[${PYTHON_USEDEP}]
+	>=dev-python/click-didyoumean-0.0.3[${PYTHON_USEDEP}]
+	>=dev-python/click-plugins-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/click-repl-0.1.6[${PYTHON_USEDEP}]
+	<dev-python/kombu-6.0[${PYTHON_USEDEP}]
+	>=dev-python/kombu-5[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/vine-5[${PYTHON_USEDEP}]
+	<dev-python/vine-6[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		>=dev-python/boto3-1.9.178[${PYTHON_USEDEP}]
+		>=dev-python/case-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/moto-1.3.7[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6.2[${PYTHON_USEDEP}]
+		dev-python/pytest-celery[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/pyzmq-13.1.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/docutils[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-click-2.5.0[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+# testsuite needs it own source
+DISTUTILS_IN_SOURCE_BUILD=1
+distutils_enable_tests pytest
+distutils_enable_sphinx docs --no-autodoc
+
+python_install_all() {
+	# Main celeryd init.d and conf.d
+	newinitd "${FILESDIR}/celery.initd-r2" celery
+	newconfd "${FILESDIR}/celery.confd-r2" celery
+
+	if use examples; then
+		docinto examples
+		dodoc -r examples/.
+		docompress -x "/usr/share/doc/${PF}/examples"
+	fi
+
+	newbashcomp extra/bash-completion/celery.bash "${PN}"
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "zookeeper support" dev-python/kazoo
+	optfeature "msgpack support" dev-python/msgpack
+	#optfeature "rabbitmq support" dev-python/librabbitmq
+	#optfeature "slmq support" dev-python/softlayer_messaging
+	optfeature "eventlet support" dev-python/eventlet
+	#optfeature "couchbase support" dev-python/couchbase
+	optfeature "redis support" dev-db/redis dev-python/redis-py
+	optfeature "gevent support" dev-python/gevent
+	optfeature "auth support" dev-python/pyopenssl
+	optfeature "pyro support" dev-python/pyro:4
+	optfeature "yaml support" dev-python/pyyaml
+	optfeature "memcache support" dev-python/pylibmc
+	optfeature "mongodb support" dev-python/pymongo
+	optfeature "sqlalchemy support" dev-python/sqlalchemy
+	optfeature "sqs support" dev-python/boto
+	#optfeature "cassandra support" dev-python/cassandra-driver
+}