dev-util/blueprint-compiler: Drop 0.1.0_pre20220419

Signed-off-by: Yuan Liao <liaoyuan@gmail.com>

2 files changed, 0 insertions, 99 deletions

diff --git a/dev-util/blueprint-compiler/Manifest b/dev-util/blueprint-compiler/Manifest
index 7535fa13b..12df55944 100644
--- a/dev-util/blueprint-compiler/Manifest
+++ b/dev-util/blueprint-compiler/Manifest
@@ -1,2 +1 @@
-DIST blueprint-compiler-0.1.0_pre20220419.tar.gz 53439 BLAKE2B 1683356aa10ffdc6b1f6b5d072a301bbc2cdde2eb986f22aa83c269af1fa8cc100910ca790b2b94056db926221b42d2f8309019ee10442374d7e915ab5ec2ed3 SHA512 9017667728723d0e9358ffe9e868f743093cadc7434275c5805f406da72d5cd7afcb5af394c5610446ab6cebdddafc52f65723e16950b3aae47c8739b77e3ef1
 DIST blueprint-compiler-v0.2.0.tar.bz2 45480 BLAKE2B 64c477070ea684002dc1e38eac8d22633ae7b46efb9887733118838c04d2c4e386d3825b3e07dcba1adada83afad439025d082d3bd74d2d737c1f5552085a716 SHA512 dfb16354a13a18c0e6db52dc0b88ab7339fbf3eb56541d0a273551c009c7f05c651d41814397986ef2cebdefb6d4e57d0eb3690dd2a7a9eebfb0cfb23e96e3e6
diff --git a/dev-util/blueprint-compiler/blueprint-compiler-0.1.0_pre20220419.ebuild b/dev-util/blueprint-compiler/blueprint-compiler-0.1.0_pre20220419.ebuild
deleted file mode 100644
index a4993541d..000000000
--- a/dev-util/blueprint-compiler/blueprint-compiler-0.1.0_pre20220419.ebuild
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9..10} )
-
-inherit meson python-r1
-
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://gitlab.gnome.org/jwestman/blueprint-compiler.git"
-else
-	# Upstream has not started to tag releases yet, so each keyworded (normal)
-	# ebuild is to be based on a Git commit snapshot at this moment.
-	# Live ebuild: Might be intentionally left blank
-	# Normal ebuild: Fill in commit SHA-1 object name to this variable's value
-	GIT_COMMIT="f77550413c2cc987368b3aac3643c7bfb8b522ef"
-	KEYWORDS="~amd64"
-
-	SRC_URI="https://gitlab.gnome.org/jwestman/blueprint-compiler/-/archive/${GIT_COMMIT}/blueprint-compiler-${GIT_COMMIT}.tar.gz -> ${P}.tar.gz"
-	S="${WORKDIR}/${PN}-${GIT_COMMIT}"
-fi
-
-DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
-HOMEPAGE="https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/"
-
-LICENSE="LGPL-3+"
-SLOT="0"
-
-IUSE="doc test"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-RESTRICT="!test? ( test )"
-
-BDEPEND="
-	${PYTHON_DEPS}
-	doc? (
-		dev-python/sphinx[${PYTHON_USEDEP}]
-		dev-python/furo[${PYTHON_USEDEP}]
-	)
-"
-
-DEPEND="
-	test? (
-		gui-libs/gtk:4[introspection]
-	)
-"
-
-RDEPEND="
-	${PYTHON_DEPS}
-"
-
-src_configure() {
-	local emesonargs=(
-		$(meson_use doc docs)
-	)
-	python_foreach_impl meson_src_configure
-}
-
-src_compile() {
-	python_foreach_impl meson_src_compile
-}
-
-src_test() {
-	python_foreach_impl meson_src_test
-}
-
-src_install() {
-	my_src_install() {
-		local exe="${ED}/usr/bin/${PN}"
-
-		# Meson installs a Python script at ${ED}/usr/bin/${PN}; on
-		# Gentoo, the script should go into ${ED}/usr/lib/python-exec,
-		# and ${ED}/usr/bin/${PN} should be a symbolic link to
-		# ${ED}/usr/lib/python-exec/python-exec2.
-		#
-		# When multiple PYTHON_TARGETS are enabled, then after the
-		# package has been installed for one Python implementation,
-		# Meson will follow the ${ED}/usr/bin/${PN} symbolic link and
-		# install the script at ${ED}/usr/lib/python-exec/python-exec2
-		# for the remaining implementations, leading to file collision.
-		if [[ -L "${exe}" ]]; then
-			rm -v "${exe}" || die "Failed to remove symbolic link ${exe}"
-		fi
-
-		meson_src_install
-		python_doscript "${exe}"
-		python_optimize
-
-		# Install Sphinx-generated documentation only once
-		# since the documentation is supposed to be identical
-		# between different Python implementations
-		use doc && HTML_DOCS=( "${BUILD_DIR}/docs"/* )
-	}
-
-	python_foreach_impl my_src_install
-	einstalldocs
-}