net-wireless/eiwd: new package

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>

5 files changed, 118 insertions, 0 deletions

diff --git a/net-wireless/eiwd/Manifest b/net-wireless/eiwd/Manifest
new file mode 100644
index 0000000000..65b311ab97
--- /dev/null
+++ b/net-wireless/eiwd/Manifest
@@ -0,0 +1 @@
+DIST eiwd-1.6-1.tar.xz 940492 BLAKE2B ba5256396510f6d092516ec210b7d274d7e984a1c7bf9f7ed5a8e1b7f0939c233d8a7e0d934f068c5bda5c7f54425134dca972ff1845396e7ed35298139e2923 SHA512 7f0e8522b01c455f16f43682b1f8b76ef15587f53cf4f6976870d9797e1d8f40f5c8146d23b277a3d555594ab534b832a837190734840429f58acce27e16edef
diff --git a/net-wireless/eiwd/eiwd-1.6.1.ebuild b/net-wireless/eiwd/eiwd-1.6.1.ebuild
new file mode 100644
index 0000000000..b00e9d12fe
--- /dev/null
+++ b/net-wireless/eiwd/eiwd-1.6.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+MY_PV="$(ver_rs 2 '-')"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="iwd without dbus"
+HOMEPAGE="https://github.com/dylanaraps/eiwd"
+SRC_URI="https://github.com/dylanaraps/eiwd/releases/download/${MY_PV}/${MY_P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+system-ell"
+
+COMMON_DEPEND="system-ell? ( ~dev-libs/ell-0.30 )"
+BDEPEND="virtual/pkgconfig"
+RDEPEND="${COMMON_DEPEND}
+	!net-wireless/iwd
+	net-wireless/wireless-regdb"
+DEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	append-cflags "-fsigned-char"
+	local myeconfargs=(
+		--sysconfdir="${EPREFIX}"/etc/iwd --localstatedir="${EPREFIX}"/var
+		--disable-dbus
+		$(use_enable system-ell external-ell)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	keepdir /var/lib/iwd
+	newinitd "${FILESDIR}/iwd.initd" iwd
+}
diff --git a/net-wireless/eiwd/eiwd-9999.ebuild b/net-wireless/eiwd/eiwd-9999.ebuild
new file mode 100644
index 0000000000..90565bddc6
--- /dev/null
+++ b/net-wireless/eiwd/eiwd-9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic git-r3
+
+MY_PV="$(ver_rs 2 '-')"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="iwd without dbus"
+HOMEPAGE="https://github.com/dylanaraps/eiwd"
+EGIT_REPO_URI="https://github.com/dylanaraps/eiwd.git"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS=""
+IUSE="+system-ell"
+
+COMMON_DEPEND="system-ell? ( ~dev-libs/ell-0.30 )"
+BDEPEND="virtual/pkgconfig"
+RDEPEND="${COMMON_DEPEND}
+	!net-wireless/iwd
+	net-wireless/wireless-regdb"
+DEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	append-cflags "-fsigned-char"
+	local myeconfargs=(
+		--sysconfdir="${EPREFIX}"/etc/iwd --localstatedir="${EPREFIX}"/var
+		--disable-dbus
+		$(use_enable system-ell external-ell)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	keepdir /var/lib/iwd
+	newinitd "${FILESDIR}/iwd.initd" iwd
+}
diff --git a/net-wireless/eiwd/files/iwd.initd b/net-wireless/eiwd/files/iwd.initd
new file mode 100644
index 0000000000..e2b1040076
--- /dev/null
+++ b/net-wireless/eiwd/files/iwd.initd
@@ -0,0 +1,13 @@
+#!/sbin/openrc-run
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+command="/usr/libexec/iwd"
+pidfile="/run/iwd.pid"
+command_background="yes"
+
+depend() {
+	after bootmisc modules
+	before dns dhcpcd net
+	keyword -shutdown
+}
diff --git a/net-wireless/eiwd/metadata.xml b/net-wireless/eiwd/metadata.xml
new file mode 100644
index 0000000000..12f4ea9d03
--- /dev/null
+++ b/net-wireless/eiwd/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<!-- maintainer-needed -->
+	<upstream>
+		<remote-id type="github">dylanaraps/eiwd</remote-id>
+	</upstream>
+	<use>
+		<flag name="system-ell">
+			Use the system-wide <pkg>dev-libs/ell</pkg>instead of bundled.
+		</flag>
+	</use>
+</pkgmetadata>