1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/faust-cchardet/faust-cchardet-2.1.19.ebuild b/dev-python/faust-cchardet/faust-cchardet-2.1.19.ebuild
new file mode 100644
index 000000000..bf9510785
--- /dev/null
+++ b/dev-python/faust-cchardet/faust-cchardet-2.1.19.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+inherit distutils-r1
+
+GIT_SUBMODULES=(
+	"PyYoshi uchardet bdb8a0376ddf5d3cab6397be0bad98dad106d77f src/ext/uchardet"
+)
+submodule_uris() {
+	local g
+	for g in "${GIT_SUBMODULES[@]}"; do
+		g=(${g})
+		echo "https://github.com/${g[0]}/${g[1]}/archive/${g[2]}.tar.gz -> ${g[1]}-${g[2]}.tar.gz"
+	done
+}
+
+DESCRIPTION="universal character encoding detector"
+HOMEPAGE="https://github.com/faust-streaming/cChardet"
+SRC_URI="
+	https://github.com/faust-streaming/cChardet/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	$(submodule_uris)
+"
+
+S="${WORKDIR}/cChardet-${PV}"
+
+LICENSE="MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="dev-python/cython"
+
+distutils_enable_tests pytest
+
+src_unpack() {
+	default
+
+	local g
+	for g in "${GIT_SUBMODULES[@]}"; do
+		g=(${g})
+		mv "${WORKDIR}/${g[1]}-${g[2]}"/* "${S}/${g[3]}" || die "could not move submodule ${g[2]}"
+	done
+}