blob: 29ce25bafefcbc1888637d166df0d232b6cb44fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
DOCS_BUILDER="mkdocs"
DOCS_DEPEND="dev-python/mkdocs-material"
inherit distutils-r1 docs optfeature
DESCRIPTION="Async database support for Python."
HOMEPAGE="
https://www.encode.io/databases/
https://github.com/encode/databases
"
SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
>=dev-python/sqlalchemy-1.4.0[${PYTHON_USEDEP}]
<dev-python/sqlalchemy-1.5.0[${PYTHON_USEDEP}]
"
BDEPEND="test? (
dev-python/aiopg[${PYTHON_USEDEP}]
dev-python/aiosqlite[${PYTHON_USEDEP}]
dev-python/async-timeout[${PYTHON_USEDEP}]
dev-python/asyncpg[${PYTHON_USEDEP}]
dev-python/psycopg[${PYTHON_USEDEP}]
dev-python/pymysql[${PYTHON_USEDEP}]
dev-python/starlette[${PYTHON_USEDEP}]
)"
distutils_enable_tests pytest
EPYTEST_DESELECT=(
tests/test_connection_options.py::test_mysql_pool_size
tests/test_connection_options.py::test_mysql_explicit_pool_size
tests/test_connection_options.py::test_mysql_ssl
tests/test_connection_options.py::test_mysql_explicit_ssl
tests/test_connection_options.py::test_mysql_pool_recycle
tests/test_databases.py
tests/test_integration.py::test_integration
)
python_prepare_all() {
# do not install LICENSE to /usr/
sed -i -e '/data_files/d' setup.py || die
# fix tests
sed -i -e '/databases.backends.mysql/d' tests/test_connection_options.py || die
distutils-r1_python_prepare_all
}
python_test() {
TEST_DATABASE_URLS="" epytest
}
pkg_postinst() {
optfeature "postgresql support" dev-python/asyncpg dev-python/psycopg
optfeature "mysql support" dev-python/pymysql
optfeature "sqlite support" dev-python/aiosqlite
optfeature "postgresql+aiopg support" dev-python/aiopg
}
|