Merge updates from master

5 files changed, 242 insertions, 3 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index a00bfc9ac6d2..763255c230b8 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,4 +1,5 @@
 DIST ImageMagick-6.9.7-4.tar.xz 8797776 SHA256 68842c55ed9c958b84aae17974961cefff4212bf7146f09fd15c09dbdc2d9629 SHA512 9ee9cf01c486575183a67e418bdbdcf4ac2b7ea2f9ff033db6a74f8271af0567da00f020dd8c18e042221d20444bed21d5d5256944ddeaf9916b62bf1844acf6 WHIRLPOOL 7c75006dafd28bb0fe02e130b4fcbae5fe54c6fbfdb29ba6b49796a14354e7aeb56b80c498eb57a4a8c7b383af025406dfeba66735ba89fd35d61125b51e7d41
 DIST ImageMagick-6.9.7-9.tar.xz 8796644 SHA256 831e0ed90fd85a63d8282ba66878953a11a2b1e6912b9104f7cb5593a0891bbb SHA512 1954e14e5da1d24b44c69352444ad66aa08be2d3698d5efa7e71703064cbae56fd75eb72ba178ac8fdb4513b9eaebe87adcc6cfd19b9e11eda1b0c2704e12481 WHIRLPOOL 1a9fe789dd7b954b47c97bf33b3615784731285dea54eed684a191885748c1db3b0c66c0b2d20f294a426ce029e2b11da8e7a4b1a9fc8d12ebf5565ba3349e01
 DIST ImageMagick-6.9.8-3.tar.xz 8819084 SHA256 5dd5804f803d01f0c0c6fc0f3da68cc8e4c638b5ff56770f8481bbe202411316 SHA512 78d467a3d6f38d9b2f30d9d5154a45396a082e7c31119e37a3646080fbc3a87447e9fd73ffbdcc8cf45e9370bdab963d7e5b674d5933ac6d52e017371d7c1460 WHIRLPOOL 80ad8fe7afd7a564739426d1e8eee8d85900c420a07a1edc7ef047958537c0fbd5674e9f3385cc7448e903b4ebd08c24e21bdf3e0615d42614a740df7abba914
-DIST ImageMagick-7.0.5-4.tar.xz 8316148 SHA256 4a1dde5bdfec0fc549955a051be25b7ff96dfb192060997699e43c7ce0f06ab2 SHA512 4f2af87c3da5723b1b8030faf37c7b3a09f25301749f9b5c35c175b825c5f8758f29d8d36bb0acb285d2beae13aa45d906455cefec37a247c039ba98222b41ef WHIRLPOOL 8a30a7cc27666b5f7f5bd349bc06face8a836d7bce9e99a17782333e3eb54257a6635e47da791e3264d5fd1961c1558bbc3490daf93380fd5cfa62e763866e8d
+DIST ImageMagick-6.9.8-6.tar.xz 8772452 SHA256 dc587a30457d1b42fa980fe7d94bfad906407ad811335e60f5eb673b3a17afeb SHA512 9bd05db02f0565063d6513620567e54b66521dc49b9dd26a83e68d1aab3ca599b9b34ba0661df2e3a88042b88806db156f6a1e9598c34d76307c0fb4ad0c4271 WHIRLPOOL de126414da7b8bfc99102ad7ff3e3d181bc584561344b29c927f66531ecf797ef5e95100279af7a20372a13be67829565d47c612676089419d413ddfa84fa632
+DIST ImageMagick-7.0.5-7.tar.xz 8261496 SHA256 f72d089074d6c968bab38d1c18b22bd92c876e7ae23f7261db0b7c3552186586 SHA512 b634d4bba00fb3a344af350c29d8ecb397901c05cafece1de136a1d8f95e65a1324b4f035b5ed021d505980e8b373ddd4995805b73ed48a257039aa829e58855 WHIRLPOOL 1ac5e950fdf57e2000fae3c1817725e2ea86f41e6e51661a4cb93a47b83cba9864874d3d3662831fbd66308e2816744d9a7532ebeea1c615e3bad9a879a5f0a9
diff --git a/media-gfx/imagemagick/imagemagick-7.0.5.4.ebuild b/media-gfx/imagemagick/imagemagick-6.9.8.6.ebuild
index c1082ae7128d..c1082ae7128d 100644
--- a/media-gfx/imagemagick/imagemagick-7.0.5.4.ebuild
+++ b/media-gfx/imagemagick/imagemagick-6.9.8.6.ebuild
diff --git a/media-gfx/imagemagick/imagemagick-7.0.5.7.ebuild b/media-gfx/imagemagick/imagemagick-7.0.5.7.ebuild
new file mode 100644
index 000000000000..c1082ae7128d
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.5.7.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	CONFIG_SHELL=$(type -P bash) \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k openjp2) \
+		$(use_with lcms) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp \
+		--with-gcc-arch=no-automagic
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/ati/card:/dev/dri/card"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}
diff --git a/sys-apps/nawk/files/nawk-20121220-parallel-build.patch b/sys-apps/nawk/files/nawk-20121220-parallel-build.patch
index 45a3e5624a40..ee6421c665ad 100644
--- a/sys-apps/nawk/files/nawk-20121220-parallel-build.patch
+++ b/sys-apps/nawk/files/nawk-20121220-parallel-build.patch
@@ -1,5 +1,5 @@
---- makefile.orig	2013-02-06 10:26:36.452829647 -0700
-+++ makefile	2013-02-07 09:12:13.293898947 -0700
+--- a/makefile	2013-02-06 10:26:36.452829647 -0700
++++ b/makefile	2013-02-07 09:12:13.293898947 -0700
 @@ -44,7 +44,7 @@
  LISTING = awk.h proto.h awkgram.y lex.c b.c main.c maketab.c parse.c \
  	lib.c run.c tran.c 
diff --git a/sys-apps/nawk/nawk-20121220-r3.ebuild b/sys-apps/nawk/nawk-20121220-r3.ebuild
new file mode 100644
index 000000000000..a52e72d09b28
--- /dev/null
+++ b/sys-apps/nawk/nawk-20121220-r3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Brian Kernighan's pattern scanning and processing language"
+HOMEPAGE="http://cm.bell-labs.com/cm/cs/awkbook/index.html"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-macos"
+
+RDEPEND="
+	app-eselect/eselect-awk
+	!sys-freebsd/freebsd-ubin"
+
+DEPEND="
+	${RDEPEND}
+	virtual/yacc"
+
+S="${WORKDIR}"
+
+PATCHES=( "${FILESDIR}/${P}"-parallel-build.patch )
+
+DOCS=( README FIXES )
+
+src_prepare() {
+	default
+	rm -v ytab.[hc] || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		CPPFLAGS=-DHAS_ISBLANK \
+		ALLOC="${LDFLAGS}" \
+		YACC=$(type -p yacc) \
+		YFLAGS="-d"
+}
+
+src_install() {
+	newbin a.out "${PN}"
+	sed \
+		-e 's/awk/nawk/g' \
+		-e 's/AWK/NAWK/g' \
+		-e 's/Awk/Nawk/g' \
+		awk.1 > "${PN}".1 || die "manpage patch failed"
+	doman "${PN}.1"
+	einstalldocs
+}
+
+pkg_postinst() {
+	eselect awk update ifunset
+}
+
+pkg_postrm() {
+	eselect awk update ifunset
+}