gnome-extra/nemo: add 5.8.4

Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 134 insertions, 0 deletions

diff --git a/gnome-extra/nemo/Manifest b/gnome-extra/nemo/Manifest
index 88dd2213e672..d28a814885da 100644
--- a/gnome-extra/nemo/Manifest
+++ b/gnome-extra/nemo/Manifest
@@ -1 +1,2 @@
 DIST nemo-5.6.5.tar.gz 1498469 BLAKE2B 1ead71e79170e977e21dd631f7875198b3aa411689bd59b9c64b50a3c3b02a396f2b1cbc1e1420bf242004a6a724b8498e7e0cdd2b48b9d5e54ed97d21331cba SHA512 b37181e419d5a9427931d29f2addf9faebca7d74d8b8337dc9cb62ebc3b8f8d9dcef978bc6fc9be65efc41bd2a153685849f10cac9e28ffb3ccb3a8dee5aa739
+DIST nemo-5.8.4.tar.gz 1506620 BLAKE2B 948735bf75df2a0f8be9f5ddb29a73d6bf5127a6d932325855976da21334feb2c905b1a26c0ef285c8317b7e42223de098505802b1dde7a5e6fc1f4942d11681 SHA512 b636d5bbaa18e9259f74f086ed55e528be8dcfabdddbcdb0e3c82e3b93d0aa1b77573319f83df1529f1c473cdabbcab7280baa4169b482b5b9ecf6ade6e04427
diff --git a/gnome-extra/nemo/metadata.xml b/gnome-extra/nemo/metadata.xml
index a7f8d807b96f..c675b141f70a 100644
--- a/gnome-extra/nemo/metadata.xml
+++ b/gnome-extra/nemo/metadata.xml
@@ -12,4 +12,7 @@
 	<upstream>
 		<remote-id type="github">linuxmint/nemo</remote-id>
 	</upstream>
+	<use>
+		<flag name="tracker">Add support for <pkg>app-misc/tracker</pkg> search</flag>
+	</use>
 </pkgmetadata>
diff --git a/gnome-extra/nemo/nemo-5.8.4.ebuild b/gnome-extra/nemo/nemo-5.8.4.ebuild
new file mode 100644
index 000000000000..00ed28c44e22
--- /dev/null
+++ b/gnome-extra/nemo/nemo-5.8.4.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit meson gnome2-utils python-single-r1 readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="A file manager for Cinnamon, forked from Nautilus"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/nemo"
+SRC_URI="https://github.com/linuxmint/nemo/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="exif gtk-doc +nls selinux test tracker xmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# https://github.com/linuxmint/nemo/issues/2501
+RESTRICT="test"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	>=dev-libs/glib-2.45.7:2[dbus]
+	>=dev-libs/gobject-introspection-0.9.12:=
+	>=dev-libs/libxml2-2.7.8:2
+	>=gnome-extra/cinnamon-desktop-5.8:0=
+	gnome-extra/libgsf:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.10.0:3[introspection]
+	x11-libs/libX11
+	>=x11-libs/pango-1.40.0
+	>=x11-libs/xapp-2.6.1
+
+	exif? ( >=media-libs/libexif-0.6.20 )
+	selinux? ( sys-libs/libselinux )
+	tracker? ( app-misc/tracker:3 )
+	xmp? ( >=media-libs/exempi-2.2.0:= )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	x11-themes/adwaita-icon-theme
+
+	nls? ( >=gnome-extra/cinnamon-translations-5.8 )
+"
+PDEPEND="
+	>=gnome-base/gvfs-0.1.2
+"
+DEPEND="
+	${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.31.0
+	>=dev-util/intltool-0.40.1
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+PATCHES=(
+	# Undo the switch to untex as it's not packaged.
+	"${FILESDIR}/${PN}-5.0.3-use-detex.patch"
+)
+
+DISABLE_AUTOFORMATTING="yes"
+FORCE_PRINT_ELOG="yes"
+DOC_CONTENTS="
+${PN} functionality can be extended by installing other packages.
+
+sys-apps/gnome-disk-utility - Mount archive files
+gnome-extra/nemo-fileroller - Extract/Create archive files
+
+${PN} search capabilities can be extended through external
+helpers. Install any of the following packages to make
+their associated file types searchable.
+
+epub                     - app-arch/unzip and app-text/html2text
+Image metadata           - media-gfx/exif
+MP3 tags                 - media-sound/id3
+Microsoft Office .doc    - app-text/catdoc
+Microsoft Office .xls    - dev-python/xlrd
+OpenDocument/LibreOffice - app-text/odt2txt or app-office/unoconv
+PDF                      - app-text/poppler[utils]
+PostScript               - app-text/ghostscript-gpl
+TeX                      - app-text/texlive-core
+"
+
+src_prepare() {
+	default
+	python_fix_shebang files/usr/share/nemo/actions install-scripts
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif)
+		$(meson_use xmp)
+		$(meson_use selinux)
+		$(meson_use tracker)
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}