app-text/cherrytree: add 0.99.47

Closes: https://bugs.gentoo.org/833995
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/app-text/cherrytree/Manifest b/app-text/cherrytree/Manifest
index 8b27173b2f61..2c2c695aec1a 100644
--- a/app-text/cherrytree/Manifest
+++ b/app-text/cherrytree/Manifest
@@ -1,2 +1,3 @@
 DIST cherrytree-0.99.0_p20200523.tar.gz 10452221 BLAKE2B cbac9b5b1c4fc1454d229a56784a59f1622b134d640db720e496cc0f1b4f95ee097343572f33d8b0626903f58ae188e8b85065144fcad8c647732e7eddadd0b9 SHA512 4eb142368bd1d3838879669d5bf1742689b02f08f50edd51a6fa6f22fef83d0f1871147aca3c346e9fcd1193c3f494e112cdc9e10eda4b3124587f605f89cc54
 DIST cherrytree-0.99.37.tar.gz 17983743 BLAKE2B 42e5464f4cba4364dbbdabe5daaf80517a62f3f4b2c1c3efa764e9b10dfae492bf335403d24a7a33d9b7c8cd55a0c55ad359ffca1f639fa7622e00a416defd60 SHA512 2413924d03c65dfad820bc2b1e345b7dd74b69d11a10ee0d333400936eb31368f53f2aee77a3dd708adb3d4b91578c0499766bca4c85537822e9c4b3d41c6800
+DIST cherrytree_0.99.47.tar.xz 2457904 BLAKE2B 1072de8ed62757a873a258dc9ab1e9e186128b520e7f02e0a2cd8e7e0173232af7db85e3293efd21b577e51b6f5e55cca0cf35631e34279e32dc07836335b742 SHA512 2611be4c24a188793aa6785d96b33ec91c0957b30616352e1cb2cd12f296e39c29666d37a03016be6c934898bf6deb98af74c2c345d9c70f138f62ac6b10f023
diff --git a/app-text/cherrytree/cherrytree-0.99.47.ebuild b/app-text/cherrytree/cherrytree-0.99.47.ebuild
new file mode 100644
index 000000000000..6da5672e3e52
--- /dev/null
+++ b/app-text/cherrytree/cherrytree-0.99.47.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake python-any-r1 xdg
+
+DESCRIPTION="A hierarchical note taking application (C++ version)"
+HOMEPAGE="https://www.giuspen.com/cherrytree https://github.com/giuspen/cherrytree"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/giuspen/cherrytree"
+	S="${WORKDIR}/${P}/future"
+else
+	SRC_URI="https://github.com/giuspen/cherrytree/releases/download/${PV}/${P/-/_}.tar.xz"
+	#SRC_URI="https://github.com/giuspen/cherrytree/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${P/-/_}
+
+	KEYWORDS="~amd64 ~x86"
+	# S="${WORKDIR}/${PN}-${COMMIT}/future"
+fi
+
+# GPL-3 — future/src/ct (CherryTree)
+# LGPL-2.1 — future/src/7za (7zip)
+# MIT — future/src/fmt (libfmt)
+LICENSE="GPL-3 LGPL-2.1 MIT"
+SLOT="0"
+IUSE="nls test"
+
+# Has deps that aren't available in ::gentoo repo
+RESTRICT="test"
+
+RDEPEND="app-i18n/uchardet
+	app-text/gspell:=
+	>=dev-cpp/glibmm-2.64.2:2
+	dev-cpp/gtkmm:3.0
+	dev-cpp/gtksourceviewmm:3.0
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/pangomm:1.4
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/libfmt:=
+	dev-libs/libxml2:2
+	dev-libs/spdlog
+	net-misc/curl
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/pango"
+DEPEND="${RDEPEND}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')"
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+	test? ( dev-util/cpputest )"
+
+python_check_deps() {
+	has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	# disable compress man pages
+	sed -i -e \
+		'/install(FILES/s|${MANFILE_FULL_GZ}|${CMAKE_SOURCE_DIR}/data/cherrytree.1|' \
+		CMakeLists.txt || die
+
+	if [[ ${PV} != *9999 ]]; then
+		sed -i \
+			-e "/^set(CT_VERSION/s|\"\(.*\)\"|\"${PV}\"|" \
+			CMakeLists.txt || die
+	fi
+
+	# python_fix_shebang .
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXEC="${PYTHON}"
+		-DUSE_NLS=$(usex nls)
+		-DBUILD_TESTING=$(usex test)
+		-DUSE_SHARED_FMT_SPDLOG=ON
+	)
+
+	cmake_src_configure
+}