app-text/wiki2beamer: Python 3.10 + EAPI 8

Closes: https://bugs.gentoo.org/845609
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.30, Repoman-3.0.3

1 files changed, 44 insertions, 0 deletions

diff --git a/app-text/wiki2beamer/wiki2beamer-0.10.0-r1.ebuild b/app-text/wiki2beamer/wiki2beamer-0.10.0-r1.ebuild
new file mode 100644
index 000000000000..8c2706adfa50
--- /dev/null
+++ b/app-text/wiki2beamer/wiki2beamer-0.10.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit python-single-r1
+
+DESCRIPTION="Tool to produce LaTeX Beamer code from wiki-like input"
+
+MY_P=wiki2beamer-v${PV}
+HOMEPAGE="https://wiki2beamer.github.io/"
+SRC_URI="https://github.com/wiki2beamer/wiki2beamer/archive/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+ FDL-1.3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +examples"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	doc? ( dev-ruby/asciidoctor )"
+
+S="${WORKDIR}/wiki2beamer-${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-doc-examples-makefile.patch
+	"${FILESDIR}"/${P}-doc-man-makefile.patch
+)
+
+src_compile() {
+	use doc && emake -C doc/man/ wiki2beamer.1
+}
+
+src_install() {
+	use examples && dodoc -r doc/examples
+
+	use doc && doman doc/man/${PN}.1
+	dodoc ChangeLog README.md
+
+	python_doscript code/${PN}
+}