dev-python/certifi: Bump to v2018.04.16

Ebuild changes:
===============
- We no longer install bundled cacert.pem. Instead we
  refer to system's CA store.

Closes: https://github.com/gentoo/gentoo/pull/8109
Closes: https://bugs.gentoo.org/627558
Package-Manager: Portage-2.3.31, Repoman-2.3.9

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/certifi/certifi-2018.4.16.ebuild b/dev-python/certifi/certifi-2018.4.16.ebuild
new file mode 100644
index 000000000000..bc9a884dd33c
--- /dev/null
+++ b/dev-python/certifi/certifi-2018.4.16.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3 )
+
+inherit distutils-r1 prefix readme.gentoo-r1 versionator
+
+DESCRIPTION="Python package for providing Mozilla's CA Bundle"
+HOMEPAGE="http://certifi.io/ https://pypi.org/project/certifi"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="app-misc/ca-certificates"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+# Do not drop this patch -- this will affect system's security
+PATCHES=( "${FILESDIR}"/certifi-2018.4.16-use-system-cacerts.patch )
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	eprefixify certifi/core.py
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	local DOC_CONTENTS="
+		In Gentoo, we don't use certifi's bundled CA certificates.
+		Instead we remove bundled cacert.pem and patch certifi
+		to return system's CA certificates.
+	"
+	readme.gentoo_create_doc
+
+	# Precaution -- nothing should use bundled CA certificates
+	find "${D}" -name 'cacert.pem' -delete || die "Failed to delete bundled CA certificates"
+}