dev-python/protobuf-python: EAPI 8, remove namespace dep

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 91 insertions, 21 deletions

diff --git a/dev-python/protobuf-python/protobuf-python-3.19.3-r1.ebuild b/dev-python/protobuf-python/protobuf-python-3.19.3-r1.ebuild
new file mode 100644
index 000000000000..e29ffa1c55e7
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.19.3-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2008-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="
+	https://developers.google.com/protocol-buffers/
+	https://github.com/protocolbuffers/protobuf/
+"
+if [[ "${PV}" != "9999" ]]; then
+	SRC_URI="
+		https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz
+			-> protobuf-${PV}.tar.gz
+	"
+fi
+S="${WORKDIR}/protobuf-${PV}/python"
+
+LICENSE="BSD"
+SLOT="0/30"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+"
+RDEPEND="${BDEPEND}"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+distutils_enable_tests setup.py
+
+python_prepare_all() {
+	pushd "${WORKDIR}/protobuf-${PV}" > /dev/null || die
+	eapply "${FILESDIR}/${PN}-3.19.0-google.protobuf.pyext._message.PyUnknownFieldRef.patch"
+	eapply_user
+	popd > /dev/null || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	DISTUTILS_ARGS=(--cpp_implementation)
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name "*.pth" -type f -delete || die
+}
diff --git a/dev-python/protobuf-python/protobuf-python-9999.ebuild b/dev-python/protobuf-python/protobuf-python-9999.ebuild
index 6eb7e579382a..34d32b251ad3 100644
--- a/dev-python/protobuf-python/protobuf-python-9999.ebuild
+++ b/dev-python/protobuf-python/protobuf-python-9999.ebuild
@@ -1,7 +1,8 @@
 # Copyright 2008-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="7"
+EAPI=8
+
 PYTHON_COMPAT=( python3_{8..10} )
 
 inherit distutils-r1
@@ -14,32 +15,39 @@ if [[ "${PV}" == "9999" ]]; then
 fi
 
 DESCRIPTION="Google's Protocol Buffers - Python bindings"
-HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
-if [[ "${PV}" == "9999" ]]; then
-	SRC_URI=""
-else
-	SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+HOMEPAGE="
+	https://developers.google.com/protocol-buffers/
+	https://github.com/protocolbuffers/protobuf/
+"
+if [[ "${PV}" != "9999" ]]; then
+	SRC_URI="
+		https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz
+			-> protobuf-${PV}.tar.gz
+	"
 fi
+S="${WORKDIR}/protobuf-${PV}/python"
 
 LICENSE="BSD"
 SLOT="0/30"
 KEYWORDS=""
-IUSE=""
 
-BDEPEND="${PYTHON_DEPS}
+BDEPEND="
+	${PYTHON_DEPS}
 	~dev-libs/protobuf-${PV}
-	dev-python/namespace-google[${PYTHON_USEDEP}]
-	dev-python/six[${PYTHON_USEDEP}]"
-DEPEND="${PYTHON_DEPS}
-	~dev-libs/protobuf-${PV}"
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+"
 RDEPEND="${BDEPEND}"
 
-S="${WORKDIR}/protobuf-${PV}/python"
-
 if [[ "${PV}" == "9999" ]]; then
 	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
 fi
 
+distutils_enable_tests setup.py
+
 python_prepare_all() {
 	pushd "${WORKDIR}/protobuf-${PV}" > /dev/null || die
 	eapply_user
@@ -48,16 +56,11 @@ python_prepare_all() {
 	distutils-r1_python_prepare_all
 }
 
-python_configure_all() {
-	mydistutilsargs=(--cpp_implementation)
-}
-
-python_test() {
-	esetup.py test
+src_configure() {
+	DISTUTILS_ARGS=(--cpp_implementation)
 }
 
 python_install_all() {
 	distutils-r1_python_install_all
-
 	find "${ED}" -name "*.pth" -type f -delete || die
 }