dev-ruby/rspec-expectations: Add rspec 3.7

Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-ruby/rspec-expectations/rspec-expectations-3.7.0.ebuild b/dev-ruby/rspec-expectations/rspec-expectations-3.7.0.ebuild
new file mode 100644
index 000000000000..39b3e3075673
--- /dev/null
+++ b/dev-ruby/rspec-expectations/rspec-expectations-3.7.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="https://github.com/rspec/rspec-expectations"
+SRC_URI="https://github.com/rspec/${PN}/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="MIT"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+SUBVERSION="$(get_version_component_range 1-2)"
+
+ruby_add_rdepend ">=dev-ruby/diff-lcs-1.2.0 <dev-ruby/diff-lcs-2
+	=dev-ruby/rspec-support-${SUBVERSION}*"
+
+ruby_add_bdepend "test? (
+		>=dev-ruby/rspec-mocks-3.2.0:3
+		>=dev-ruby/rspec-support-3.5.0:3
+	)"
+
+all_ruby_prepare() {
+	# Don't set up bundler: it doesn't understand our setup.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# Remove the Gemfile to avoid running through 'bundle exec'
+	rm -f Gemfile || die
+
+	# fix up the gemspecs
+	sed -i \
+		-e '/git ls/d' \
+		-e '/add_development_dependency/d' \
+		"${RUBY_FAKEGEM_GEMSPEC}" || die
+}