kde-apps: Add KDE Release Service 19.12.3

Package-Manager: Portage-2.3.92, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/kde-apps/kwrite/kwrite-19.12.3.ebuild b/kde-apps/kwrite/kwrite-19.12.3.ebuild
new file mode 100644
index 000000000000..8217ae17d00d
--- /dev/null
+++ b/kde-apps/kwrite/kwrite-19.12.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_ORG_NAME="kate"
+ECM_HANDBOOK="optional"
+KFMIN=5.63.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Simple text editor based on KDE Frameworks"
+HOMEPAGE="https://kde.org/applications/utilities/org.kde.kwrite"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="activities"
+
+DEPEND="
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# delete colliding kate translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "kwrite*" -delete || die
+		rm -rf po/*/docs/kate* || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		-DBUILD_addons=FALSE
+		-DBUILD_kate=FALSE
+	)
+	use handbook && mycmakeargs+=( -DBUILD_katepart=FALSE )
+
+	ecm_src_configure
+}