net-misc/rygel: version bump to 0.28.2

Package-Manager: portage-2.2.26

2 files changed, 83 insertions, 0 deletions

diff --git a/net-misc/rygel/Manifest b/net-misc/rygel/Manifest
index d60dda267007..acca6b1db886 100644
--- a/net-misc/rygel/Manifest
+++ b/net-misc/rygel/Manifest
@@ -1,2 +1,3 @@
 DIST rygel-0.26.1.tar.xz 2191348 SHA256 390740609e34399b886ddb9a8f7eca25055ad72048dfdd869edf02999b1e1d8f SHA512 3b0c168a9c974a8900a1e8ab9de764e24ed1b8b11df8f24ee0522ccd85cffce6477b36e4d83a7e278f7e9198865d800c35673ed0819e800bc406279a59d16fc8 WHIRLPOOL 54416b603a8a72695cfe59fd559006a12878ab0c51d6e21e3867b5fd36be6b2d33c144275ea9f05e3cfa822e0023fbc28dd9b0e1ae62f2e880718ca5e5235805
 DIST rygel-0.28.1.tar.xz 2228652 SHA256 d9a145cf1ecb10654d63741cd8c7d37fbaf413d4d3c35f89a8b08e39512bf174 SHA512 3c078450f530a0aeb1ef81b06349951dbbfdc7d4a9c5aa60c40cdca398dd2e9a2037451036ff94cafd5f73ca9479016ae480fc5646d5192fedd363ee2588cf41 WHIRLPOOL c85a1ebd49993e6901d356344f2e24be9a0242beff97979ce7d9abeb5e197a82721541db14d758c590122ccd4d4c18e75ab33bfc59c8a0e04c568eab02381703
+DIST rygel-0.28.2.tar.xz 2244840 SHA256 9ea23df7186caac5f1aad3137edf6d507d339b9a469fc3133df4043fa66b61f5 SHA512 23d8ff2315c12e70f3c160f9047709bc3d491b3a4782a02d7c7c1a136700dcf55b880feb6a2a2ea08978377fe234a63fbb05d0dc79bfa05978886ec23da46300 WHIRLPOOL f21503dbcd2b1280501e6b16c4a55f3de436bcc91b7f77220111d60dbec942778df231c35c7d065a5ccd4ccd608ffa256258b36139340d2d2b7fa27a46295d1d
diff --git a/net-misc/rygel/rygel-0.28.2.ebuild b/net-misc/rygel/rygel-0.28.2.ebuild
new file mode 100644
index 000000000000..d38212af637a
--- /dev/null
+++ b/net-misc/rygel/rygel-0.28.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 virtualx
+
+DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
+HOMEPAGE="https://wiki.gnome.org/Projects/Rygel"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X +introspection +sqlite tracker test transcode"
+
+# The deps for tracker? and transcode? are just the earliest available
+# version at the time of writing this ebuild
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	>=dev-libs/libgee-0.8:0.8
+	>=dev-libs/libxml2-2.7:2
+	>=media-libs/gupnp-dlna-0.9.4:2.0
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=media-libs/libmediaart-0.7:2.0
+	media-plugins/gst-plugins-soup:1.0
+	>=net-libs/gssdp-0.13
+	>=net-libs/gupnp-0.20.14
+	>=net-libs/gupnp-av-0.12.4
+	>=net-libs/libsoup-2.44:2.4
+	>=sys-apps/util-linux-2.20
+	x11-misc/shared-mime-info
+	introspection? ( >=dev-libs/gobject-introspection-1.33.4:= )
+	sqlite? (
+		>=dev-db/sqlite-3.5:3
+		dev-libs/libunistring:=
+	)
+	tracker? ( >=app-misc/tracker-0.16:= )
+	transcode? (
+		media-libs/gst-plugins-bad:1.0
+		media-plugins/gst-plugins-twolame:1.0
+		media-plugins/gst-plugins-libav:1.0
+	)
+	X? ( >=x11-libs/gtk+-3:3 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# Maintainer only
+#	>=dev-lang/vala-0.22
+#   dev-libs/libxslt
+
+src_configure() {
+	# We set xsltproc because man pages are provided by upstream
+	# and we do not want to regenerate them automagically.
+	gnome2_src_configure \
+		XSLTPROC=$(type -P false) \
+		--enable-gst-launch-plugin \
+		--enable-mediathek-plugin \
+		--with-media-engine=gstreamer \
+		--enable-nls \
+		$(use_enable introspection) \
+		$(use_enable sqlite media-export-plugin) \
+		$(use_enable test tests) \
+		$(use_enable tracker tracker-plugin) \
+		$(use_with X ui)
+}
+
+src_install() {
+	gnome2_src_install
+	# Autostart file is not placed correctly, bug #402745
+	# https://bugs.launchpad.net/ubuntu/+source/rygel/+bug/827030
+	insinto /etc/xdg/autostart
+	doins "${D}"/usr/share/applications/rygel.desktop
+	rm "${D}"/usr/share/applications/rygel.desktop
+}