sys-apps/smartmontools: add 7.4

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 158 insertions, 1 deletions

diff --git a/sys-apps/smartmontools/Manifest b/sys-apps/smartmontools/Manifest
index c8bdef502e27..729a30cb14cd 100644
--- a/sys-apps/smartmontools/Manifest
+++ b/sys-apps/smartmontools/Manifest
@@ -1 +1,2 @@
 DIST smartmontools-7.3.tar.gz 1043932 BLAKE2B 119fd4aded487796ffd38050ddf8c7dd69cc6f3950650cb0315846292fd4a6594d949d87c51ed46717d6aaadb332c68f655514d1fde89600d51f3fe36f8df1ca SHA512 08afe8b0a6a39e742160cd4e4c03fc7aff7b1ae8681b906360f0932277dc99e361b7606b2373bdf42425cf9453480a5f4344bc040ebc2fa26a03bd52f02a6ac0
+DIST smartmontools-7.4.tar.gz 1094955 BLAKE2B fbf7888b92b6be4892a206e1c0fae1cb7c45fe0d62270c5fe713a540616e3599c67dd3297ad8c1cd344987e1fe95ae7c5e92db8e13ef622b3316b3780fbb4052 SHA512 439fbf8d0e77fbe1d5a9fb100e655a7e47a82382ce8e1a4e942541a4dfbdff3391caa635e8d354d0e87c10ae79cb97aa6d24915f9f193620d763b384baf2e753
diff --git a/sys-apps/smartmontools/smartmontools-7.4.ebuild b/sys-apps/smartmontools/smartmontools-7.4.ebuild
new file mode 100644
index 000000000000..deaefc5a3442
--- /dev/null
+++ b/sys-apps/smartmontools/smartmontools-7.4.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic systemd
+if [[ ${PV} == 9999 ]] ; then
+	ESVN_REPO_URI="https://svn.code.sf.net/p/smartmontools/code/trunk/smartmontools"
+	ESVN_PROJECT="smartmontools"
+	inherit autotools subversion
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+fi
+
+DESCRIPTION="Tools to monitor storage systems to provide advanced warning of disk degradation"
+HOMEPAGE="https://www.smartmontools.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="caps +daemon selinux static systemd +update-drivedb"
+
+DEPEND="
+	caps? (
+		static? ( sys-libs/libcap-ng:=[static-libs] )
+		!static? ( sys-libs/libcap-ng:= )
+	)
+	selinux? (
+		sys-libs/libselinux:=
+	)
+"
+RDEPEND="
+	${DEPEND}
+	daemon? ( virtual/mailx )
+	selinux? ( sec-policy/selinux-smartmon )
+	systemd? ( sys-apps/systemd )
+	update-drivedb? (
+		app-crypt/gnupg
+		|| (
+			net-misc/curl
+			net-misc/wget
+			www-client/lynx
+			dev-vcs/subversion
+		)
+	)
+"
+
+REQUIRED_USE="(
+	caps? ( daemon )
+	static? ( !systemd )
+)"
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999 ]] ; then
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	# The build installs /etc/init.d/smartd, but we clobber it
+	# in our src_install, so no need to manually delete it.
+	myeconfargs=(
+		--with-drivedbdir="${EPREFIX}/var/db/${PN}" #575292
+		--with-initscriptdir="${EPREFIX}/etc/init.d"
+		#--with-smartdscriptdir="${EPREFIX}/usr/share/${PN}"
+		$(use_with caps libcap-ng)
+		$(use_with selinux)
+		$(use_with systemd libsystemd)
+		$(use_with update-drivedb gnupg)
+		$(use_with update-drivedb update-smart-drivedb)
+		$(usex systemd "--with-systemdsystemunitdir=$(systemd_get_systemunitdir)" '')
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	local db_path="/var/db/${PN}"
+	insopts -m0644 -p # preserve timestamps
+
+	if use daemon; then
+		default
+
+		newinitd "${FILESDIR}"/smartd-r1.rc smartd
+		newconfd "${FILESDIR}"/smartd.confd smartd
+	else
+		dosbin smartctl
+		doman smartctl.8
+
+		local DOCS=( AUTHORS ChangeL* COPYING INSTALL NEWS README TODO )
+		einstalldocs
+	fi
+
+	if use update-drivedb ; then
+		if ! use daemon; then
+			dosbin "${S}"/update-smart-drivedb
+		fi
+
+		exeinto /etc/cron.monthly
+		doexe "${FILESDIR}/${PN}-update-drivedb"
+	fi
+
+	if use daemon || use update-drivedb; then
+		keepdir "${db_path}"
+
+		# Install a copy of the initial drivedb.h to /usr/share/${PN}
+		# so that we can access that file later in pkg_postinst
+		# even when dealing with binary packages (bug #575292)
+		insinto /usr/share/${PN}
+		doins "${S}"/drivedb.h
+	fi
+
+	# Make sure we never install drivedb.h into the db location
+	# of the acutal image so we don't record hashes because user
+	# can modify that file
+	rm -f "${ED}${db_path}/drivedb.h" || die
+
+	# Bug #622072
+	find "${ED}"/usr/share/doc -type f -exec chmod a-x '{}' \; || die
+}
+
+pkg_postinst() {
+	if use daemon || use update-drivedb; then
+		local initial_db_file="${EROOT}/usr/share/${PN}/drivedb.h"
+		local db_path="${EROOT}/var/db/${PN}"
+
+		if [[ ! -f "${db_path}/drivedb.h" ]] ; then
+			# No initial database found
+			cp "${initial_db_file}" "${db_path}" || die
+			einfo "Default drive database which was shipped with this release of ${PN}"
+			einfo "has been installed to '${db_path}'."
+		else
+			ewarn "WARNING: There's already a drive database in '${db_path}'!"
+			ewarn "Because we cannot determine if this database is untouched"
+			ewarn "or was modified by the user you have to manually update the"
+			ewarn "drive database:"
+			ewarn ""
+			ewarn "a) Replace '${db_path}/drivedb.h' by the database shipped with this"
+			ewarn "   release which can be found in '${initial_db_file}', i.e."
+			ewarn ""
+			ewarn "     cp \"${initial_db_file}\" \"${db_path}\""
+			ewarn ""
+			ewarn "b) Run the following command as root:"
+			ewarn ""
+			ewarn "     /usr/sbin/update-smart-drivedb"
+
+			if ! use update-drivedb ; then
+				ewarn ""
+				ewarn "However, 'update-smart-drivedb' requires that you re-emerge ${PN}"
+				ewarn "with USE='update-drivedb'."
+			fi
+		fi
+	fi
+}
diff --git a/sys-apps/smartmontools/smartmontools-9999.ebuild b/sys-apps/smartmontools/smartmontools-9999.ebuild
index 9772d6259993..deaefc5a3442 100644
--- a/sys-apps/smartmontools/smartmontools-9999.ebuild
+++ b/sys-apps/smartmontools/smartmontools-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7