1 files changed, 77 insertions, 0 deletions
diff --git a/sci-chemistry/molden/molden-5.0.ebuild b/sci-chemistry/molden/molden-5.0.ebuild
new file mode 100644
index 000000000000..e4ad3b6d802d
--- /dev/null
+++ b/sci-chemistry/molden/molden-5.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit eutils fortran-2 flag-o-matic toolchain-funcs
+
+MY_P="${PN}${PV}"
+
+DESCRIPTION="Display molecular density from GAMESS-UK, GAMESS-US, GAUSSIAN and Mopac/Ampac"
+HOMEPAGE="http://www.cmbi.kun.nl/~schaft/molden/molden.html"
+SRC_URI="ftp://ftp.cmbi.kun.nl/pub/molgraph/${PN}/${MY_P}.tar.gz"
+
+LICENSE="MOLDEN"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="opengl"
+
+RDEPEND="
+	x11-libs/libXmu
+		virtual/glu
+	opengl? (
+		media-libs/freeglut
+		virtual/opengl )"
+DEPEND="${RDEPEND}
+	x11-misc/gccmakedep
+	app-editors/vim"
+	# vim provides ex, which the build system uses (surf/Makefile, at least)
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-ambfor.patch \
+		"${FILESDIR}"/${P}-overflow.patch \
+		"${FILESDIR}"/${PN}-4.8-ldflags.patch \
+		"${FILESDIR}"/${PN}-4.7-implicit-dec.patch
+	sed \
+		-e 's:makedepend:gccmakedep:g' \
+		-e "s:/usr/include/sgidefs.h::g" \
+		-i surf/Makefile || die
+	sed 's:shell g77:shell $(FC):g' -i makefile || die
+}
+
+src_compile() {
+	# Use -mieee on alpha, according to the Makefile
+	use alpha && append-flags -mieee
+
+	# Honor CC, CFLAGS, FC, and FFLAGS from environment;
+	# unfortunately a bash bug prevents us from doing typeset and
+	# assignment on the same line.
+	typeset -a args
+	args=(
+			CC="$(tc-getCC) ${CFLAGS}" \
+			FC="$(tc-getFC)" \
+			LDR="$(tc-getFC)" \
+			FFLAGS="${FFLAGS}" )
+
+	einfo "Building Molden..."
+	emake -j1 "${args[@]}"
+	if use opengl ; then
+		einfo "Building Molden OpenGL helper..."
+		emake -j1 "${args[@]}" moldenogl
+	fi
+}
+
+src_install() {
+	dobin ${PN} g${PN}
+	if use opengl ; then
+		dobin ${PN}ogl
+	fi
+
+	dodoc HISTORY README REGISTER
+	cd doc
+	uncompress * && dodoc *
+}