added ebuild for rgmanager's resource-agents (named the package rgmanager-agents)

2 files changed, 67 insertions, 0 deletions

diff --git a/sys-cluster/rgmanager-agents/Manifest b/sys-cluster/rgmanager-agents/Manifest
new file mode 100644
index 0000000..f2b8672
--- /dev/null
+++ b/sys-cluster/rgmanager-agents/Manifest
@@ -0,0 +1,2 @@
+EBUILD rgmanager-agents-3.9.2.ebuild 1678 RMD160 d843b6e0c04385f6f88ad7f6551cd7120e6ee1fd SHA1 f5afe624667171169108e345873350a62a5d1de0 SHA256 e71c35c3fa184dad4a6a80a9820cc8fea6d463bdd6b8db988f5ee49bed5b4d35
+DIST rgmanager-agents-3.9.2.tar.gz 1103104 RMD160 caad45e5b5a44810ab39c9988b894c2a66ab922c SHA1 2b300d589056bab3f5144964d81c3572f98f1750 SHA256 e62cedf54cdfec0e1532a6ca08a1b4d6e1686586001bd695e45c28eed0c4a887
diff --git a/sys-cluster/rgmanager-agents/rgmanager-agents-3.9.2.ebuild b/sys-cluster/rgmanager-agents/rgmanager-agents-3.9.2.ebuild
new file mode 100644
index 0000000..6f168a4
--- /dev/null
+++ b/sys-cluster/rgmanager-agents/rgmanager-agents-3.9.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+inherit multilib versionator
+
+CLUSTER_RELEASE="3.1.5"
+MY_PN="resource-agents"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Resource Manager Agents"
+HOMEPAGE="https://fedorahosted.org/cluster/wiki/HomePage"
+SRC_URI="https://fedorahosted.org/releases/r/e/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="~sys-cluster/rgmanager-${CLUSTER_RELEASE}
+	~sys-cluster/cman-${CLUSTER_RELEASE}"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	econf \
+		--docdir=/usr/share/doc/${P} \
+		--libdir=/usr/$(get_libdir) \
+		--localstatedir=/var \
+		--sysconfdir=/etc \
+		--with-ras-set=rgmanager
+}
+
+src_install() {
+	default
+
+	# remove useless RHEV check script and log directory
+	rm -rf "${D}/usr/sbin" "${D}/var"
+}
+
+pkg_postinst() {
+	if [[ "${ROOT}" != "/" ]] ; then
+		ewarn "You have to run 'ccs_update_schema' in the chroot-environment"
+		ewarn "to update the schema file for the cluster configuration."
+		ewarn "Otherwise you will not be able to define ressources."
+	else
+		elog "Running ccs_update_schema to update the configuration file schema"
+		/usr/sbin/ccs_update_schema
+	fi
+}
+
+pkg_postrm() {
+	if [[ "${ROOT}" != "/" ]] ; then
+		ewarn "You have to run 'ccs_update_schema' in the chroot-environment"
+		ewarn "to update the schema file for the cluster configuration."
+		ewarn "Otherwise you may be able to define ressources even though they"
+		ewarn "are not present anymore."
+	else
+		elog "Running ccs_update_schema to update the configuration file schema"
+		/usr/sbin/ccs_update_schema
+	fi
+}