net-misc/whois: add 5.5.15

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 83 insertions, 1 deletions

diff --git a/net-misc/whois/Manifest b/net-misc/whois/Manifest
index 226356a14cf5..8b41b491da4d 100644
--- a/net-misc/whois/Manifest
+++ b/net-misc/whois/Manifest
@@ -1 +1,2 @@
 DIST whois_5.5.14.tar.xz 87480 BLAKE2B 868c9dc968581535ee2b56a6293f634e2c8dc6c00703a45d4ca4f0ce6769786ee4921bd66f3a470b2a7f31808db2971b284c23b76b608bff1edbb7bbe37f892a SHA512 f190d488d7bd68717c0a83ca85709fad09c33b619c46d7e0dd12e79621fdba56b9d43480c25ef3c9df2f6ade0ee72d692bfc5d0bd96839ef92194004313d1cc6
+DIST whois_5.5.15.tar.xz 89960 BLAKE2B 50e0114b3b6c3ad143e7a1aed62e492e780a061d7151de2b0d48cc4b55b889958abaa5fc069c8c36075936fb4bf4ad3d9e15ff799c2c0e2e33a1aa31c4136272 SHA512 e173927fd3428d27bc8ab34b1a66b82d6a2cfc107245755868bdd33cb7eb1b8159e87774c3a751d9694e65b3d870b9904dc9a3c657dca385950c8a19be1fa61c
diff --git a/net-misc/whois/whois-5.5.15.ebuild b/net-misc/whois/whois-5.5.15.ebuild
new file mode 100644
index 000000000000..cd95191e70ba
--- /dev/null
+++ b/net-misc/whois/whois-5.5.15.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+MY_P=${P/-/_}
+DESCRIPTION="Improved Whois Client"
+HOMEPAGE="https://github.com/rfc1036/whois"
+
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/rfc1036/whois.git"
+else
+	SRC_URI="mirror://debian/pool/main/w/whois/${MY_P}.tar.xz"
+	#SRC_URI="https://github.com/rfc1036/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="iconv idn nls xcrypt"
+
+RDEPEND="
+	iconv? ( virtual/libiconv )
+	idn? ( net-dns/libidn2:= )
+	nls? ( virtual/libintl )
+	xcrypt? ( >=sys-libs/libxcrypt-4.1:= )
+	!xcrypt? ( virtual/libcrypt:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/xz-utils
+	>=dev-lang/perl-5
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.7.2-config-file.patch
+	"${FILESDIR}"/${PN}-5.3.0-libidn_automagic.patch
+	"${FILESDIR}"/${PN}-5.5.6-libxcrypt_automagic.patch
+)
+
+src_prepare() {
+	default
+
+	if use nls ; then
+		sed -i -e 's:#\(.*pos\):\1:' Makefile || die
+	else
+		sed -i -e '/ENABLE_NLS/s:define:undef:' config.h || die
+
+		# don't generate po files when nls is disabled (bug #419889)
+		sed -i -e '/^all:/s/ pos//' \
+			-e '/^install:/s/ install-pos//' Makefile || die
+	fi
+}
+
+src_configure() { :; } # expected no-op
+
+src_compile() {
+	unset HAVE_ICONV HAVE_LIBIDN
+
+	use iconv && export HAVE_ICONV=1
+	use idn && export HAVE_LIBIDN=1
+	use xcrypt && export HAVE_XCRYPT=1
+
+	tc-export CC
+
+	emake CFLAGS="${CFLAGS} ${CPPFLAGS}"
+}
+
+src_install() {
+	emake BASEDIR="${ED}" prefix=/usr install
+
+	insinto /etc
+	doins whois.conf
+	dodoc README debian/changelog
+}
diff --git a/net-misc/whois/whois-9999.ebuild b/net-misc/whois/whois-9999.ebuild
index 4c1dfcda83b9..cd95191e70ba 100644
--- a/net-misc/whois/whois-9999.ebuild
+++ b/net-misc/whois/whois-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit toolchain-funcs