app-crypt/yubikey-manager: bump to 0.6.0, enable tests, add readme.gentoo

Version bump to 0.6.0. The tests seem to run just fine with the
distributed tarball.

The package app-crypt/ccid is needed for pcscd to provide support for
USB devices. Create a readme about it since it's an easy thing to miss
but not so easy to debug.

Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 50 insertions, 0 deletions

diff --git a/app-crypt/yubikey-manager/yubikey-manager-0.6.0.ebuild b/app-crypt/yubikey-manager/yubikey-manager-0.6.0.ebuild
new file mode 100644
index 000000000000..3379be37dba5
--- /dev/null
+++ b/app-crypt/yubikey-manager/yubikey-manager-0.6.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+inherit readme.gentoo-r1 distutils-r1
+
+DESCRIPTION="Python library and command line tool for configuring a YubiKey"
+HOMEPAGE="https://developers.yubico.com/yubikey-manager/"
+SRC_URI="https://developers.yubico.com/${PN}/Releases/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	app-crypt/libu2f-host
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/pyscard[${PYTHON_USEDEP}]
+	dev-python/pyusb[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7)
+	sys-auth/ykpers
+"
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOC_CONTENTS
+
+	distutils-r1_python_install_all
+
+	DOC_CONTENTS="
+		The 'openpgp' command may require the package 'app-crypt/ccid'
+		to be installed on the system. Furthermore, make sure that pcscd
+		daemon is running and has correct access permissions to USB
+		devices.
+	"
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}