app-i18n/ibus-libpinyin: Version bump 1.10.0 & fix boost configure

1.9.3-r1 - This patches issue with latest GCC on configure with boost
1.10.0 - This includes above patch, and also update to new major version

I submitted the patch/fix upstream as pull request
https://github.com/libpinyin/ibus-libpinyin/pull/134
and it has been merged (basically updating the boost.m4 macro to latest)

1.10.0 has additional changes as upstream has moved configuration settings
to gsettings (now requires gnome2_utils eclass)

Closes: https://bugs.gentoo.org/659328
Package-Manager: Portage-2.3.40, Repoman-2.3.9
Closes: https://github.com/gentoo/gentoo/pull/9050
Closes: https://bugs.gentoo.org/659816

1 files changed, 52 insertions, 0 deletions

diff --git a/app-i18n/ibus-libpinyin/ibus-libpinyin-1.9.3-r1.ebuild b/app-i18n/ibus-libpinyin/ibus-libpinyin-1.9.3-r1.ebuild
new file mode 100644
index 000000000000..04c2251e7b30
--- /dev/null
+++ b/app-i18n/ibus-libpinyin/ibus-libpinyin-1.9.3-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit autotools python-single-r1
+
+BOOST_M4_GIT_VERSION=282b1e01f5bc5ae94347474fd8c35cb2f7a7e65d
+
+DESCRIPTION="Intelligent Pinyin and Bopomofo input methods based on LibPinyin for IBus"
+HOMEPAGE="https://github.com/libpinyin/ibus-libpinyin https://sourceforge.net/projects/libpinyin/"
+SRC_URI="https://github.com/libpinyin/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+	boost? ( https://github.com/tsuna/boost.m4/raw/${BOOST_M4_GIT_VERSION}/build-aux/boost.m4 -> boost.${BOOST_M4_GIT_VERSION}.m4 )
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boost lua opencc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+	>=app-i18n/libpinyin-2.1.0:=
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	boost? ( dev-libs/boost:= )
+	lua? ( dev-lang/lua:0 )
+	opencc? ( app-i18n/opencc:= )"
+
+DEPEND="${RDEPEND}
+	virtual/libintl
+	virtual/pkgconfig"
+
+src_prepare() {
+	if use boost; then
+		cp "${DISTDIR}/boost.${BOOST_M4_GIT_VERSION}.m4" "m4/boost.m4" \
+			|| die "copying newer version of boost.m4 file failed"
+	fi
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-english-input-mode \
+		$(use_enable boost) \
+		$(use_enable lua lua-extension) \
+		$(use_enable opencc)
+}