app-i18n/libskk: new upstream release

Package-Manager: Portage-3.0.4, Repoman-2.3.23
Signed-off-by: Akinori Hattori <hattya@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/app-i18n/libskk/libskk-1.0.5.ebuild b/app-i18n/libskk/libskk-1.0.5.ebuild
new file mode 100644
index 000000000000..eab92a1f7f0c
--- /dev/null
+++ b/app-i18n/libskk/libskk-1.0.5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit vala virtualx
+
+DESCRIPTION="GObject-based library to deal with Japanese kana-to-kanji conversion method"
+HOMEPAGE="https://github.com/ueno/libskk"
+SRC_URI="https://github.com/ueno/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection nls static-libs"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libgee:0.8
+	x11-libs/libxkbcommon
+	introspection? ( dev-libs/gobject-introspection )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	vala_src_prepare
+	default
+}
+
+src_configure() {
+	econf \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable static-libs static)
+}
+
+src_test() {
+	export GSETTINGS_BACKEND="memory"
+	virtx emake check
+}
+
+src_install() {
+	default
+	use static-libs || find "${ED}" -name '*.la' -delete || die
+}