dev-libs/libutf8proc: new upstream release

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Akinori Hattori <hattya@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-libs/libutf8proc/libutf8proc-2.5.0.ebuild b/dev-libs/libutf8proc/libutf8proc-2.5.0.ebuild
new file mode 100644
index 000000000000..776f2dc9a1e3
--- /dev/null
+++ b/dev-libs/libutf8proc/libutf8proc-2.5.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+DESCRIPTION="A clean C Library for processing UTF-8 Unicode data"
+HOMEPAGE="https://github.com/JuliaStrings/utf8proc"
+SRC_URI="https://github.com/JuliaStrings/${PN#lib}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+IUSE="static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( =app-i18n/unicode-data-13.0* )"
+S="${WORKDIR}/${P#lib}"
+
+PATCHES=( "${FILESDIR}"/${PN}-grapheme-test.patch )
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${ED}" \
+		prefix="/usr" \
+		libdir="/usr/$(get_libdir)" \
+		install
+	use static-libs || find "${ED}" -name '*.a' -delete || die
+}
+
+src_test() {
+	cp "${EPREFIX}"/usr/share/unicode-data/{Normalization,auxiliary/GraphemeBreak}Test.txt data || die
+
+	emake CC="$(tc-getCC)" check
+}