dev-ml/ocsigen-toolkit: Bump to 1.0.0

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-ml/ocsigen-toolkit/ocsigen-toolkit-1.0.0.ebuild b/dev-ml/ocsigen-toolkit/ocsigen-toolkit-1.0.0.ebuild
new file mode 100644
index 000000000000..79b2c5de5529
--- /dev/null
+++ b/dev-ml/ocsigen-toolkit/ocsigen-toolkit-1.0.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit findlib
+
+DESCRIPTION="User interface widgets for Ocsigen applications"
+HOMEPAGE="https://github.com/ocsigen/ocsigen-toolkit"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="+ocamlopt debug"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/ocsigen/ocsigen-toolkit"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/ocsigen/ocsigen-toolkit/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+RDEPEND="dev-lang/ocaml:=[ocamlopt?]
+	>dev-ml/js_of_ocaml-2.7:=
+	>=dev-ml/eliom-5.1:=[ppx]
+	dev-ml/ppx_deriving:=
+	dev-ml/calendar:=
+	dev-ml/lwt:="
+DEPEND="${RDEPEND}
+	dev-ml/opam"
+
+src_compile() {
+	emake \
+		DEBUG="$(usex debug yes no)" \
+		NATIVE="$(usex ocamlopt yes no)" \
+		all
+}
+
+src_install() {
+	findlib_src_preinst
+	OCAMLPATH="${OCAMLFIND_DESTDIR}" emake install
+	opam-installer -i \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		${PN}.install || die
+	dodoc README.md
+}