dev-perl/Coro: Bump to version 6.514.0

- Patches all upstremed
- Add USE="examples"
- Fix automagic building of EV/Event

Upstream:
- Fixes for supporting API changes in Perl 5.22, 5.24, 5.26...
- disable FORTIFY_SOURCE to avoid fortifed-but-broken longjmp in some
  libc's
- Partially improved JIT allocation
- Fixes for statevar types on newer perls
- safe_cancel no longer croaks from already destroyed threads.

Package-Manager: Portage-2.3.8, Repoman-2.3.3

dev-perl/Coro: fix automagic builds

Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-perl/Coro/Coro-6.514.0.ebuild b/dev-perl/Coro/Coro-6.514.0.ebuild
new file mode 100644
index 000000000000..5cbecd4664f6
--- /dev/null
+++ b/dev-perl/Coro/Coro-6.514.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DIST_AUTHOR=MLEHMANN
+DIST_VERSION=6.514
+DIST_EXAMPLES=( "eg/*" )
+inherit perl-module
+
+DESCRIPTION="The only real threads in perl"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ev event"
+
+RDEPEND="
+	>=dev-perl/AnyEvent-5
+	ev? ( >=dev-perl/EV-4.0.0 )
+	event? ( >=dev-perl/Event-0.890.0 )
+	>=dev-perl/Guard-0.500.0
+	virtual/perl-Scalar-List-Utils
+	>=virtual/perl-Storable-2.150.0
+	dev-perl/common-sense
+"
+DEPEND="${RDEPEND}
+	dev-perl/Canary-Stability
+	>=virtual/perl-ExtUtils-MakeMaker-6.520.0
+"
+PATCHES=(
+	"${FILESDIR}/${PV}-ev-config.patch"
+)
+src_configure() {
+	local myopts=()
+	use ev && myopts+=("EV")
+	use event && myopts+=( "Event" )
+	GENTOO_OPTS="${myopts[@]}" perl-module_src_configure
+}