dev-python/flask-themes: bump to 0.1.3_p20180112, add PyPy3+Py3.7, doc

Also fix tests and dependencies.

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/flask-themes/flask-themes-0.1.3_p20180112.ebuild b/dev-python/flask-themes/flask-themes-0.1.3_p20180112.ebuild
new file mode 100644
index 000000000000..c0e38edd02a2
--- /dev/null
+++ b/dev-python/flask-themes/flask-themes-0.1.3_p20180112.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_COMMIT="9eac2dcc9b81c3af29c2386ce1afba9b446562bf"
+
+DESCRIPTION="Infrastructure for theming support in Flask applications"
+HOMEPAGE="https://pythonhosted.org/Flask-Themes/"
+# https://github.com/maxcountryman/flask-themes/issues/8
+SRC_URI="https://github.com/maxcountryman/${PN}/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/flask-0.6[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+# No need to depend on dev-python/flask-sphinx-themes,
+# it is bundled in docs/_themes
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+
+python_prepare_all() {
+	sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests -v || die "Tests failed under ${EPYTHON}"
+}