dev-python/pygments: Add version bump 2.5.2

Signed-off-by: Guillaume Seren <guillaumeseren@gmail.com>
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.79, Repoman-2.3.16

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/pygments/pygments-2.5.2.ebuild b/dev-python/pygments/pygments-2.5.2.ebuild
new file mode 100644
index 000000000000..c74e33c5dd70
--- /dev/null
+++ b/dev-python/pygments/pygments-2.5.2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} pypy pypy3 )
+
+inherit distutils-r1 bash-completion-r1
+
+MY_PN="Pygments"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Pygments is a syntax highlighting package written in Python"
+HOMEPAGE="https://pygments.org/ https://pypi.org/project/Pygments/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		virtual/ttf-fonts
+	)"
+
+distutils_enable_sphinx doc
+
+python_test() {
+	cp -r -l tests "${BUILD_DIR}"/ || die
+	pytest "${BUILD_DIR}"/tests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	newbashcomp external/pygments.bashcomp pygmentize
+}