dev-ruby/tilt: add 2.0.7

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-ruby/tilt/tilt-2.0.7.ebuild b/dev-ruby/tilt/tilt-2.0.7.ebuild
new file mode 100644
index 000000000000..2d2b204f530d
--- /dev/null
+++ b/dev-ruby/tilt/tilt-2.0.7.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md docs/TEMPLATES.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Thin interface over template engines to make their usage as generic as possible"
+HOMEPAGE="https://github.com/rtomayko/tilt"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+# Block on some of the potential test dependencies. These dependencies
+# are optional for the test suite, and we don't want to depend on all of
+# them to faciliate keywording and stabling.
+ruby_add_bdepend "test? (
+	dev-ruby/bluecloth
+	dev-ruby/coffee-script
+	dev-ruby/erubis
+	dev-ruby/nokogiri
+	!!<dev-ruby/maruku-0.7.2 )"
+
+ruby_add_rdepend "!!<dev-ruby/tilt-1.4.1-r2:0"
+
+all_ruby_prepare() {
+	rm Gemfile || die
+	sed -e '/bundler/I s:^:#:' -i Rakefile test/test_helper.rb || die
+
+	# Avoid tests with minor syntax differences since this happens all
+	# the time when details in the dependencies change.
+	sed -e '/test_smarty_pants_true/,/^    end/ s:^:#:' \
+		-e '/test_smart_quotes_true/,/^  end/ s:^:#:' -i test/tilt_markdown_test.rb || die
+	sed -e '/smartypants when :smart is set/,/^    end/ s:^:#:' -i test/tilt_rdiscounttemplate_test.rb || die
+}