games-rpg/soltys: EAPI8, ebuild improvements

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 29 insertions, 42 deletions

diff --git a/games-rpg/soltys/soltys-1.0-r2.ebuild b/games-rpg/soltys/soltys-1.0-r2.ebuild
index e9d29906063f..3b59a9cabce4 100644
--- a/games-rpg/soltys/soltys-1.0-r2.ebuild
+++ b/games-rpg/soltys/soltys-1.0-r2.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit eutils
+EAPI=8
+
+inherit desktop wrapper
 
 DESCRIPTION="Classic adventure game"
 HOMEPAGE="https://wiki.scummvm.org/index.php/Soltys"
@@ -10,55 +11,41 @@ SRC_URI="l10n_en? ( mirror://sourceforge/scummvm/${PN}-en-v${PV}.zip )
 	l10n_es? ( mirror://sourceforge/scummvm/${PN}-es-v${PV}.zip )
 	l10n_pl? ( mirror://sourceforge/scummvm/${PN}-pl-v${PV}.zip )
 	!l10n_en? ( !l10n_es? ( !l10n_pl? ( mirror://sourceforge/scummvm/${PN}-en-v${PV}.zip ) ) )
-	http://www.scummvm.org/images/cat-soltys.png"
+	http://www.scummvm.org/images/cat-${PN}.png"
+S="${WORKDIR}"
 
 LICENSE="Soltys"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="l10n_en l10n_es l10n_pl"
 
-RDEPEND=">=games-engines/scummvm-1.5"
-DEPEND="app-arch/unzip"
-
-S="${WORKDIR}"
+RDEPEND="games-engines/scummvm"
+BDEPEND="app-arch/unzip"
 
 src_unpack() {
-	if use l10n_en || ( ! use l10n_en && ! use l10n_es && ! use l10n_pl ) ; then
-		mkdir -p en || die
-		unpack ${PN}-en-v${PV}.zip
-		mv vol.{cat,dat} en/ || die
-	fi
-	if use l10n_es ; then
-		mkdir -p es || die
-		unpack ${PN}-es-v${PV}.zip
-		mv soltys-es-v1-0/vol.{cat,dat} es/ || die
-	fi
-	if use l10n_pl ; then
-		mkdir -p pl || die
-		unpack ${PN}-pl-v${PV}.zip
-		mv vol.{cat,dat} pl/ || die
-	fi
-}
-
-src_prepare() {
-	default
-	rm -rf license.txt soltys-es-v1-0
+	MY_L10N=( $(usev l10n_en) $(usev l10n_es) $(usev l10n_pl) )
+	[[ ${MY_L10N} ]] || MY_L10N=( l10n_en )
+
+	local lang
+	for lang in "${MY_L10N[@]//l10n_/}"; do
+		mkdir ${lang} || die
+		unpack ${PN}-${lang}-v${PV}.zip
+		if [[ ${lang} == es ]]; then
+			mv ${PN}-${lang}-v$(ver_rs 1 -)/vol.{cat,dat} ${lang}/ || die
+		else
+			mv vol.{cat,dat} ${lang}/ || die
+		fi
+	done
 }
 
 src_install() {
 	insinto /usr/share/${PN}
-	doins -r *
-	newicon "${DISTDIR}"/cat-soltys.png soltys.png
-	if use l10n_en || ( ! use l10n_en && ! use l10n_es && ! use l10n_pl ) ; then
-		make_wrapper soltys-en "scummvm -f -p \"/usr/share/${PN}/en\" soltys" .
-		make_desktop_entry ${PN}-en "Soltys (English)" soltys
-	fi
-	if use l10n_es ; then
-		make_wrapper soltys-es "scummvm -f -p \"/usr/share/${PN}/es\" soltys" .
-		make_desktop_entry ${PN}-es "Soltys (Español)" soltys
-	fi
-	if use l10n_pl ; then
-		make_wrapper soltys-pl "scummvm -f -p \"/usr/share/${PN}/pl\" soltys" .
-		make_desktop_entry ${PN}-pl "Soltys (Polski)" soltys
-	fi
+	local lang
+	for lang in "${MY_L10N[@]//l10n_/}"; do
+		doins -r ${lang}
+		make_wrapper ${PN}-${lang} "scummvm -f -p \"${EPREFIX}/usr/share/${PN}/${lang}\" ${PN}"
+		make_desktop_entry ${PN}-${lang} "Soltys (${lang})"
+	done
+
+	newicon "${DISTDIR}"/cat-${PN}.png ${PN}.png
 }