lxde-base/lxterminal: version bump to 0.3.1 (CVE-2016-10369).

Bug: https://bugs.gentoo.org/635992
Closes: https://bugs.gentoo.org/607838
Closes: https://bugs.gentoo.org/595904

- Adjusted HOMEPAGE (avoid redirect).
- Adjusted tarball from.gz to .xz.
- Make repoman happy by re-adding ~arm64.
- Add LINGUAS handling.
- Add handling of live ebuild.

Package-Manager: Portage-2.3.13, Repoman-2.3.3
Closes: https://github.com/gentoo/gentoo/pull/5362

1 files changed, 47 insertions, 0 deletions

diff --git a/lxde-base/lxterminal/lxterminal-0.3.1.ebuild b/lxde-base/lxterminal/lxterminal-0.3.1.ebuild
new file mode 100644
index 000000000000..c6b5993d83cd
--- /dev/null
+++ b/lxde-base/lxterminal/lxterminal-0.3.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="af ar be bg bn bn_IN ca cs da de el en_GB eo es et eu fa fi fo fr frp gl
+he hr hu id is it ja kk ko lg lt ml ms nb nl nn pa pl ps pt pt_BR ro ru sk sl sr
+sr@latin sv te th tr tt_RU ug uk ur ur_PK vi zh_CN zh_TW"
+PLOCALE_BACKUP="en_GB"
+
+inherit autotools l10n
+
+DESCRIPTION="Lightweight vte-based tabbed terminal emulator for LXDE"
+HOMEPAGE="https://wiki.lxde.org/en/LXTerminal"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/lxde/${PN}"
+	inherit git-r3
+	KEYWORDS=""
+else
+	SRC_URI="mirror://sourceforge/lxde/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gtk3"
+
+RDEPEND="dev-libs/glib:2
+	!gtk3? ( x11-libs/gtk+:2 x11-libs/vte:0 )
+	gtk3?  ( x11-libs/gtk+:3 x11-libs/vte:2.91 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext
+	>=dev-util/intltool-0.40.0"
+
+src_prepare() {
+	default
+	eautoreconf
+
+	export LINGUAS="${LINGUAS:-${PLOCALE_BACKUP}}"
+	l10n_get_locales > po/LINGUAS || die
+}
+
+src_configure() {
+	econf --enable-man $(use_enable gtk3)
+}