summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndrey Utkin <andrey_utkin@gentoo.org>2020-03-11 22:35:18 +0000
committerAndrey Utkin <andrey_utkin@gentoo.org>2020-03-11 23:49:54 +0000
commit7520ba89529789e3c497abf1396c290073a4336e (patch)
tree587f1f12a6ac7bd1777bf92a272e33e4035069c0 /media-libs/libv4l/libv4l-1.18.0.ebuild
parentsys-devel/gcc: 9.2.0: cut 6 patchset (diff)
downloadgentoo-7520ba89529789e3c497abf1396c290073a4336e.tar.gz
gentoo-7520ba89529789e3c497abf1396c290073a4336e.tar.bz2
gentoo-7520ba89529789e3c497abf1396c290073a4336e.zip
media-libs/libv4l: add new version 1.18.0
Cloned from 1.16.6 with stable keywords dropped to stable. Package-Manager: Portage-2.3.66, Repoman-2.3.16 Signed-off-by: Andrey Utkin <andrey_utkin@gentoo.org>
Diffstat (limited to 'media-libs/libv4l/libv4l-1.18.0.ebuild')
-rw-r--r--media-libs/libv4l/libv4l-1.18.0.ebuild66
1 files changed, 66 insertions, 0 deletions
diff --git a/media-libs/libv4l/libv4l-1.18.0.ebuild b/media-libs/libv4l/libv4l-1.18.0.ebuild
new file mode 100644
index 000000000000..3aa962795920
--- /dev/null
+++ b/media-libs/libv4l/libv4l-1.18.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit libtool linux-info multilib-minimal
+
+MY_P="v4l-utils-${PV}"
+
+DESCRIPTION="Separate libraries ebuild from upstream v4l-utils package"
+HOMEPAGE="https://git.linuxtv.org/v4l-utils.git"
+SRC_URI="https://linuxtv.org/downloads/v4l-utils/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="jpeg"
+
+RDEPEND="jpeg? ( >=virtual/jpeg-0-r2:0=[${MULTILIB_USEDEP}] )
+ !elibc_glibc? ( sys-libs/argp-standalone )
+ virtual/libudev[${MULTILIB_USEDEP}]
+ !media-tv/v4l2-ctl
+ !<media-tv/ivtv-utils-1.4.0-r2"
+DEPEND="${RDEPEND}
+ virtual/os-headers
+"
+BDEPEND="virtual/pkgconfig
+ sys-devel/gettext"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=( "${FILESDIR}"/${PN}-1.16.6-gcc10-fno-common.patch )
+
+pkg_setup() {
+ CONFIG_CHECK="~SHMEM"
+ linux-info_pkg_setup
+}
+
+src_prepare() {
+ default
+ elibtoolize
+}
+
+multilib_src_configure() {
+ # Hard disable the flags that apply only to the utils.
+ ECONF_SOURCE=${S} \
+ econf \
+ --disable-static \
+ --disable-qv4l2 \
+ --disable-qvidcap \
+ --disable-v4l-utils \
+ $(use_with jpeg)
+}
+
+multilib_src_compile() {
+ emake -C lib
+}
+
+multilib_src_install() {
+ emake -j1 -C lib DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+ dodoc ChangeLog README.lib* TODO
+ find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}