media-sound/rplay: new revision with EAPI=6.

The original purpose of this new revision was to fix the use of
einstall reported in bug 521564. However, einstall proved necessary,
so along with the update to EAPI=6 -- where einstall is banned -- I
inlined its behavior.

The multilib and eutils eclasses, now unused, were dropped. The latest
debian patchset was also included.

Package-Manager: portage-2.2.28

1 files changed, 53 insertions, 0 deletions

diff --git a/media-sound/rplay/rplay-3.3.2-r2.ebuild b/media-sound/rplay/rplay-3.3.2-r2.ebuild
new file mode 100644
index 000000000000..823271ffd02f
--- /dev/null
+++ b/media-sound/rplay/rplay-3.3.2-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools user
+
+DESCRIPTION="Play sounds on remote Unix systems without data transfer"
+HOMEPAGE="http://rplay.doit.org/"
+SRC_URI="${HOMEPAGE}dist/${P}.tar.gz
+	mirror://debian/pool/main/r/${PN}/${PN}_${PV}-16.debian.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND="media-sound/gsm"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${WORKDIR}/debian/patches"
+	"${FILESDIR}/${P}-built-in_function_exit-r1.patch"
+)
+
+pkg_setup() {
+	enewgroup rplayd ""
+	enewuser rplayd "" "" "" rplayd
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-rplayd-user=rplayd \
+		--enable-rplayd-group=rplayd
+}
+
+src_install() {
+	# This is borrowed from the old einstall helper, and is necessary
+	# (at least some of variables).
+	emake prefix="${ED}/usr" \
+		datadir="${ED}/usr/share" \
+		infodir="${ED}/usr/share/info" \
+		localstatedir="${ED}/var/lib" \
+		mandir="${ED}/usr/share/man" \
+		sysconfdir="${ED}/etc" \
+		install
+}