net-ftp/ncftp: Update HOMEPAGE/SRC_URI/A

- Use HTTPS for HOMEPAGE and SRC_URI
- Update A because why not, and also because upstream changed the
  source tarball considerably (again):

 NcFTP Change Log:
  ================

  -3.2.6, 2016-09-23
  +3.2.6, 2016-12-04
...
 58 files changed, 1538 insertions(+), 863 deletions(-)

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/net-ftp/ncftp/ncftp-3.2.6-r2.ebuild b/net-ftp/ncftp/ncftp-3.2.6-r2.ebuild
new file mode 100644
index 000000000000..30b5c3cc3f0b
--- /dev/null
+++ b/net-ftp/ncftp/ncftp-3.2.6-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools toolchain-funcs
+
+DESCRIPTION="An extremely configurable ftp client"
+HOMEPAGE="https://www.ncftp.com/"
+SRC_URI="
+	https://ftp.mirrorservice.org/sites/ftp.${PN}.com/${PN}/${P}-src.tar.xz
+"
+
+LICENSE="Clarified-Artistic"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x86-solaris"
+IUSE="pch"
+
+DEPEND="
+	sys-libs/ncurses:*
+"
+RDEPEND="
+	${DEPEND}
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.2.6-fno-common.patch
+)
+
+src_prepare() {
+	default
+
+	AT_M4DIR=autoconf_local/ eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+	LC_ALL="C" \
+	LIBS="$( $(tc-getPKG_CONFIG) --libs ncurses)" \
+		econf \
+		$(use_enable pch precomp) \
+		--disable-ccdv \
+		--disable-universal
+}
+
+src_install() {
+	default
+	dodoc README.txt doc/*.txt
+	docinto html
+	dodoc doc/html/*.html
+}