net-ftp/yafc: fix build for clang16

- add new homepage
- patch autoreconf
- runs eautoreconf in ebuild

Closes: https://bugs.gentoo.org/731160
Closes: https://bugs.gentoo.org/783381
Closes: https://bugs.gentoo.org/831240
Closes: https://bugs.gentoo.org/882231
Closes: https://bugs.gentoo.org/885289
Signed-off-by: Pascal Jäger <pascal.jaeger@leimstift.de>
Closes: https://github.com/gentoo/gentoo/pull/28624
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/net-ftp/yafc/yafc-1.3.7-r2.ebuild b/net-ftp/yafc/yafc-1.3.7-r2.ebuild
new file mode 100644
index 000000000000..4ee1bb082764
--- /dev/null
+++ b/net-ftp/yafc/yafc-1.3.7-r2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools bash-completion-r1
+
+DESCRIPTION="Console ftp client with a lot of nifty features"
+HOMEPAGE="https://github.com/sebastinas/yafc"
+SRC_URI="https://github.com/sebastinas/yafc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86"
+IUSE="kerberos readline socks5 ssh"
+
+RDEPEND="
+	sys-libs/ncurses:=
+	dev-libs/libbsd
+	dev-libs/openssl:0=
+	kerberos? ( virtual/krb5 )
+	readline? ( >=sys-libs/readline-6:0= )
+	socks5? ( net-proxy/dante )
+	ssh? ( net-libs/libssh )
+"
+BDEPEND="
+	virtual/pkgconfig
+	sys-devel/gettext
+	sys-apps/texinfo
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( BUGS NEWS README.md THANKS TODO )
+
+PATCHES=( "${FILESDIR}/${P}-fix-autoreconf.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	export ac_cv_ipv6=yes
+	local myeconfargs=(
+		$(use_with readline readline /usr)
+		$(use_with socks5 socks /usr)
+		$(use_with socks5 socks5 /usr)
+		$(use_with kerberos krb5)
+		$(use_with ssh)
+		--with-bash-completion="$(get_bashcompdir)"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	dodoc -r samples
+}