1 files changed, 55 insertions, 0 deletions
diff --git a/app-i18n/ibus-hangul/ibus-hangul-1.4.1.ebuild b/app-i18n/ibus-hangul/ibus-hangul-1.4.1.ebuild
new file mode 100644
index 000000000000..a2f8585fe061
--- /dev/null
+++ b/app-i18n/ibus-hangul/ibus-hangul-1.4.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+PYTHON_DEPEND="2:2.5"
+
+inherit python
+
+DESCRIPTION="The Hangul engine for IBus input platform"
+HOMEPAGE="http://code.google.com/p/ibus/"
+SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND=">=app-i18n/ibus-1.4
+	=dev-python/pygobject-2*
+	=dev-python/pygtk-2*
+	>=app-i18n/libhangul-0.1
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? (
+		dev-util/intltool
+		>=sys-devel/gettext-0.17
+		)"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	python_clean_py-compile_files
+	sed -ie "s:python:${EPYTHON}:" \
+		setup/ibus-setup-hangul.in || die
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+pkg_postinst() {
+	python_mod_optimize /usr/share/${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/share/${PN}
+}