3 files changed, 79 insertions, 0 deletions
diff --git a/dev-libs/libcbor/Manifest b/dev-libs/libcbor/Manifest
new file mode 100644
index 000000000000..5f1048aa4eb6
--- /dev/null
+++ b/dev-libs/libcbor/Manifest
@@ -0,0 +1 @@
+DIST libcbor-0.5.0.tar.gz 719348 BLAKE2B 57e15e648159e7858d9d57a8b4cb7f3682f8153248610c9a3385cf9cbdea8babaf81d596b25d44bf6d59c75de23e76cce462fa7860b294019f46636726206d5a SHA512 5c2e9610d9fbb0bfc59f89a180f70b58539a1760fd39cad696af372c164a87828a23bb4d3a54d8e9d846be5271204800f0ad63656ef830f06a0ccdd10edfdb2c
diff --git a/dev-libs/libcbor/libcbor-0.5.0.ebuild b/dev-libs/libcbor/libcbor-0.5.0.ebuild
new file mode 100644
index 000000000000..c8144619bb69
--- /dev/null
+++ b/dev-libs/libcbor/libcbor-0.5.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 )
+inherit python-any-r1 cmake-utils
+
+DESCRIPTION="CBOR protocol implementation for C and others"
+HOMEPAGE="https://github.com/pjk/libcbor"
+SRC_URI="https://github.com/PJK/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+custom-alloc doc test"
+
+BDEPEND="
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/breathe[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+RESTRICT="!test? ( test )"
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/breathe[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DCMAKE_BUILD_TYPE=Release
+		-DCBOR_CUSTOM_ALLOC=$(usex custom-alloc 'ON' 'OFF')
+		-DWITH_TESTS=$(usex test 'ON' 'OFF')
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc; then
+		pushd doc >/dev/null || die
+		emake html man
+		popd >/dev/null || die
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		dodoc -r doc/build/html
+		doman doc/build/man/*
+	fi
+}
diff --git a/dev-libs/libcbor/metadata.xml b/dev-libs/libcbor/metadata.xml
new file mode 100644
index 000000000000..db974170e19e
--- /dev/null
+++ b/dev-libs/libcbor/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>base-system@gentoo.org</email>
+		<name>Gentoo Base System</name>
+	</maintainer>
+	<use>
+		<flag name="custom-alloc">Custom, dynamically defined allocator support</flag>
+	</use>
+</pkgmetadata>