1 files changed, 30 insertions, 0 deletions
diff --git a/dev-python/pyelftools/pyelftools-0.26.ebuild b/dev-python/pyelftools/pyelftools-0.26.ebuild
new file mode 100644
index 000000000000..ba7b7d895acf
--- /dev/null
+++ b/dev-python/pyelftools/pyelftools-0.26.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1
+
+DESCRIPTION="pure-Python library for analyzing ELF files and DWARF debugging information"
+HOMEPAGE="https://pypi.org/project/pyelftools/ https://github.com/eliben/pyelftools"
+# PyPI tarball lacks some test files
+SRC_URI="https://github.com/eliben/pyelftools/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+python_test() {
+	# readelf_tests often fails due to host `readelf` changing output format
+	local t
+	for t in all_unittests examples_test ; do
+		"${PYTHON}" ./test/run_${t}.py || die "Tests fail with ${EPYTHON}"
+	done
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}