1 files changed, 41 insertions, 0 deletions
diff --git a/sci-biology/STAR/STAR-2.7.10a.ebuild b/sci-biology/STAR/STAR-2.7.10a.ebuild
new file mode 100644
index 000000000000..6b1c5b15d482
--- /dev/null
+++ b/sci-biology/STAR/STAR-2.7.10a.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="STAR aligner: align RNA-seq reads to reference genome uncompressed suffix arrays"
+HOMEPAGE="https://github.com/alexdobin/STAR"
+SRC_URI="https://github.com/alexdobin/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="sci-libs/htslib:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( README.md CHANGES.md RELEASEnotes.md doc/STARmanual.pdf )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+src_configure() {
+	tc-export CC CXX PKG_CONFIG
+}
+
+src_compile() {
+	emake -C source STAR
+}
+
+src_install() {
+	dobin source/STAR
+	einstalldocs
+}