app-arch/dtrx/dtrx-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..11} )

inherit distutils-r1 optfeature

DESCRIPTION="Do The Right eXtraction - extracts archives of different formats"
HOMEPAGE="https://github.com/dtrx-py/dtrx/
	https://pypi.org/project/dtrx/"

if [[ ${PV} == *9999* ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/${PN}-py/${PN}.git"
else
	SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="GPL-3+"
SLOT="0"

DOCS=( README.md )

pkg_postinst() {
	local supported_format
	local -a supported_formats=(
		arj
		bzip2
		cpio
		gzip
		lrzip
		lzip
		p7zip
		rpm
		unrar
		unzip
		xz-utils
		zip
		zstd
	)

	for supported_format in ${supported_formats[@]}; do
		optfeature                                                         \
			"extraction of supported archives using ${supported_format}"   \
			app-arch/${supported_format}
	done
}