games-action/barrage/barrage-1.0.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit desktop

DESCRIPTION="Violent point-and-click shooting game"
HOMEPAGE="http://lgames.sourceforge.net/Barrage/"
SRC_URI="mirror://sourceforge/lgames/${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND="
	acct-group/gamestat
	media-libs/libsdl[sound,video]
	media-libs/sdl-mixer"
DEPEND="${RDEPEND}"

src_configure() {
	econf --localstatedir="${EPREFIX}"/var/games
}

src_compile() {
	default

	# generated .desktop hardcodes icon path (and in wrong location)
	sed -i "/^Icon=/s|=.*|=${PN}|" ${PN}.desktop || die
}

src_install() {
	default

	fowners :gamestat /{usr/bin/${PN},var/games/${PN}.hscr}
	fperms g+s /usr/bin/${PN}
	fperms 660 /var/games/${PN}.hscr

	rm "${ED}"/usr/share/icons/${PN}48.png || die
	newicon ${PN}48.png ${PN}.png
}